awk match for 3rd and 4th patterns and print it in one line

Question

Initially I got the solution already in this post.

However those are only for 2 patterns. It turns out I need more than 2 patterns now, possibly the 3rd pattern and even 4th pattern.

I tried using the following solution by adding more patterns that I got from @cas

awk -v OFS=, '
match($0,/\<[[:digit:]]{1,2}\/[[:digit:]]{1,2}\/[[:digit:]]{4} [[:digit:]]{1,2}:[[:digit:]]{1,2}\>/,a) {dt = a[0]; next};
match($0,/3rd pattern/,b);
match($0,/INC-[[:digit:]]+-[[:digit:]]+/,a) {print a[0], dt; print b[0]}' filename.log

and I'm getting the following output:

INC-210305-00000426,3/6/2021 5:19

INC-20210304-00006690,3/5/2021 5:24

only adding more space. Any other suggestion how I can grep for the 3rd or 4th pattern? they are indeed located in the different lines. Below is the input:

unwantedtext unwantedtext unwantedtext unwantedtext 8/1/2022 6:15 (1st Pattern)

unwantedtext unwantedtext unwantedtext unwantedtext 
unwantedtext unwantedtext Report_A (3rd Pattern)
unwantedtext unwantedtext INC-220721-00007628 (2nd required pattern)
unwantedtext unwantedtext unwantedtext unwantedtext 
unwantedtext unwantedtext Report_B (4th) Pattern)

The desired output is as follows:

INC-220721-00007628, 8/1/2022 6:15, Report_A

And later I might need the following output as well:

INC-220721-00007628, 8/1/2022 6:15, Report_A, Report_B

I'm using Cygwin and CentOS 7 environments.

Thank you in advance for the helpful solution.

Answer 1

I'd use perl instead of awk (even gawk; the code you use is gawk-specific):

perl -l -0777 -ne '
  $time = $& if m{\b\d{1,2}/\d{1,2}/\d{4} \d{1,2}:\d{1,2}\b};
  $inc = $& if /\bINC-\d+-\d+\b/;
  @reports = /\bReport_\S+/g;
  print join ", ", $inc, $time, @reports
    if defined($time) && defined($inc)' your-file

Answer 2

In TXR:

$ txr extract.txr input
INC-220721-00007628, 8/1/2022 6:15, Report_A, Report_B

Where extract.txr is:

@(skip)@{date /[^ ]+/} @{time /[^ ]+/} (1st Pattern)
@(skip)
@(skip)@{rep1 /[^ ]+/} (3rd Pattern)
@(skip)INC-@inccode (2nd required pattern)
@(skip)
@(skip)@{rep2 /[^ ]+/} (4th) Pattern)
@(output)
INC-@inccode, @date @time, @rep1, @rep2
@(end)

We need a modicum of regex here because we are matching patterns at the ends of lines. A variable like @date capture text that may contain spaces, whereas @{date /[^ ]+/} captures a sequence of non-space characters.

Since the output is just a one-liner, we can replace the @(output)...@(end) that using a Lisp function call wrapped in @(do ...):

@(do (put-line `INC-@inccode, @date @time, @rep1, @rep2`))

Answer 3

Using any POSIX awk:

$ cat tst.awk
match($0,/([0-9]{1,2}\/){2}[0-9]{4} [0-9]{1,2}:[0-9]{1,2}/) { dt = substr($0,RSTART,RLENGTH) }
match($0,/INC(-[0-9]+){2}/) { inc  = substr($0,RSTART,RLENGTH) }
match($0,/Report_A/)        { repa = substr($0,RSTART,RLENGTH) }
match($0,/Report_B/)        { repb = substr($0,RSTART,RLENGTH) }
END { OFS=", "; print inc, dt, repa, repb }

$ awk -f tst.awk file
INC-220721-00007628, 8/1/2022 6:15, Report_A, Report_B

The above would match the target regexps mid-word. You don't show that as being a possibility in the example in your question but if that's a concern for your real data then just change it to:

$ cat tst.awk
function set(val) {
    val = substr($0,RSTART,RLENGTH)
    gsub(/^ | $/,"",val)
    return val
}
match($0,/(^| )([0-9]{1,2}\/){2}[0-9]{4} [0-9]{1,2}:[0-9]{1,2}( |$)/) { dt = set() }
match($0,/(^| )INC(-[0-9]+){2}( |$)/) { inc  = set() }
match($0,/(^| )Report_A( |$)/)        { repa = set() }
match($0,/(^| )Report_B( |$)/)        { repb = set() }
END { OFS=", "; print inc, dt, repa, repb }