zsh: How to change the color of all invisible file names in the Mac's Terminal?

Question

I'm using a Mac Silicon with the Ventura MacOS. In the Terminal app, all the file names have the same color. Take note that the default shell is zsh in Ventura, and is the one I want to use. Currently, my .zshrc config file has this content (so the directories are all shown with some color in the Terminal. I don't want to change this):

 PROMPT='%U%B%F{red}%n%u: ~%f%b'
 alias ls="ls -G"
 alias ll="ls -lG"

The -G option in BSD ls (also used on macOS) turns on colored output.

I would like to add something in there to change the color used to display hidden files (those whose name starts with a .) when using an ls option like -A that causes them to be shown. I would like all hidden files (but not directories) to be shown in some vivid red color in the Terminal (say magenta). Please, take note that I'm a noob with the Terminal commands (I only know some basic Unix commands), so I need something simple, no fancy tricks.

So how should I do this? What commands should I add into my .zshrc file above?

Answer 1

The ls command is the only responsible with the appearance of what it prints. When ls is running, zsh only wait ls to exit. (The different color zsh options deal with what zshprints).

On MacOS, the way to setup the different ls colors are presented here : https://www.cyberciti.biz/faq/apple-mac-osx-terminal-color-ls-output-option/ See "Understanding LSCOLORS values" (man ls also show how colors are handled).

Unfortunately, you can't deal with the file/directory names, but only the kind of file (directory, socket, symbolic link, etc.) changes the color according to the palette you give.

One solution would be to use an other ls command, but the one from GNU doesn't seem to handle a .*pattern (about color handling). Only *.extension. Something like LS_COLORS='.*=01;33' ls -a indicates a unrecognized prefix. (Which is normal according to http://www.bigsoft.co.uk/blog/2008/04/11/configuring-ls_colors)

Answer 2

Note that while GNU ls colouring can only be done (via $LS_COLORS usually set with the help of the dircolors utility) based on file metadata or fixed suffix, zsh completion colouring can be configured based on any pattern.

It extends GNU ls's $LS_COLORS specification with =pattern=attributes. So with:

# set LS_COLORS for GNU ls
eval "$(dircolors)"

# use same colouring for completions, but also specify magenta for hidden files
zstyle ':completion:*:default' list-colors ${(s.:.)LS_COLORS} '=.*=35'

Or if you don't have GNU ls and dircolors, just:

zstyle ':completion:*:default' list-colors ${(s.:.)LS_COLORS} '=.*=35'

(using the default colours for the rest which are similar to GNU ls').

That's using the more modern list-colors zstyle, but the syntax is the same as for $ZLS_COLORS).

Then assuming you've enabled coloured completion via compinstall or manually, you'll see hidden files in magenta.

You'll likely also want to either enable the globdots aka dotglob option (which affects all glob expansions), or add:

zstyle ':completion:*' file-patterns '*(D)'

For hidden files to be included by default in completion listings.

A minimum ~/.zshrc to test that would look like:

zstyle ':completion:*' menu select=2
zstyle ':completion:*:default' list-colors '=.*=35'
zstyle ':completion:*' file-patterns '*(D)'
autoload -Uz compinit
compinit -i

But again, best would be to use compinstall to tune the completion system to your taste and add those two list-colors and file-patterns style separately.

In any case, that's only for zsh completion listing, that won't affect ls output.