Paste files with the same names from directories and subdirectories to another directory

Question

I'm looking for a way to paste files with the same names, contained in directories and subdirectories, to another directory with the same subdirectory structure.

For instance :

Dir1/a/a/file1
Dir2/a/a/file1

Those would be pasted into this directory :

Dir3/a/a/file1

Now I found on stackexchange a piece of zsh code that I modified to get the following :

#!/bin/zsh

typeset -A files
for file (dir*/*/*/*(nN)) files[$file:t]+=$file$'\0'
for file (${(k)files}) paste -d "\0" ${(0)files[$file]} > outputDir/*/*/$file

This doesn't work, as the code doesn't understand the "*" after outputDir. If I set a precise set of subdirectories for instance ouputDir/a/a/$file it works like a charm. I don't really know zsh as I discovered it with this piece of code. How could I do to keep the same subdirectories structure for the output dir ?

Thank you for your help. Regards

Answer 1

Sounds like you rather want:

#! /bin/zsh -

typeset -A files
for file (dir*/*/*/*(nN)) files[${file#*/}]+=$file$'\0'
for file (${(k)files}) {
  mkdir -p outputDir/$file:h &&
    paste -d '\0' ${(0)files[$file]} > outputDir/$file
}

That is for the keys in that Associative array to be the paths of the files minus the first-level directory component rather than the basename (tail) of the file.