fish shell alias only in specific directory

Question

I am using fish and am working on a project with a script that's frequently invoked for build tasks called x.py. I'd like to create an alias that maps x to ./x.py. However, I only want this to apply inside that specific directory.

The fish documentation gives a fairly detailed explanation on how to make various kinds of aliases/functions/etc, but I can't find anything on how to make them directory specific.

Any help would be much appreciated

Answer 1

Three possibilities that I can think of (other than the ones that Damir suggested). First, if at all possible, I'd just test whether or not you are in the directory in a "lazy-load" function. This is similar to what Damir recommended, but it avoids the overhead of being in your startup config or in an executable script.

Lazy-load function-based solution

Create ~/.config/fish/functions/x.fish:

function x
    if [ (pwd) = "/path/to/project` ]
        ./x.py
    else
        command x
    end
end

This function will only load when called for the first time via x. This avoids the overhead of adding it to your startup config. It is also still a function, so it executes in the current fish shell, rather than starting a new shell like an executable script would.

It also falls back to any other x command that might be installed on the system in case you aren't in that directory. If you don't need this, just delete the else block.

Function which is created when you enter the project directory

If you really need to have the function only exist when you are in that directory, there are two more alternatives. First, fish functions can watch for a variable to change, and only run when it does. That variable can be $PWD to watch for a directory change.

Add the following in ~/.config/fish/conf.d/create_x.fish:

function create_x --on-variable PWD
    if [ "$PWD" = "/path/to/project" ]
        function x
            ./x.py
        end
    else
        functions --erase x
    end
end

This does require the create_x.fish function to be loaded at startup, but it will only run when you change directories. It's definitely less efficient than the first option.

Prompt-based function

Finally, you can modify your prompt function to check the current directory. This seems wasteful, but:

• funced fish_prompt

• Add the following to the bottom:

  functions --erase x
  if [ (pwd) = "/path/to/project" ]
      function x
          ./x.py
      end
  end
  

• funcsave fish_prompt

This will check to see if you are in the project directory on each prompt, and will only create the function if you are.

The funcsave places a copy of the "normal" fish_prompt in your ~/.config/fish/functions directory. Delete it to return to the normal prompt functionality.

Definitely, go with the first option if you can :-)

Answer 2

Finally, someone else who wants this!

If you're still interested I have a little project called "Dangerload" that I use to have functions dynamically loaded/unloaded based off of the directory you're in. You can copy this file into your ./config/fish/functions. Or just run fisher install redaphid/dangerload-fish

It also will check if the function has been changed on disk and automatically update the function before exection.

It's like direnv, but for fish functions.

As the name implies, this has extreme implications if you don't trust the source of the folder you're currently in. Because of this, you have to type 'dls' in once per terminal session to opt in to this behavior. haha.

I had a fancier version once, but this one just looks at a the file ./scripts/dangerload.fish and pulls the functions you want to add/remove from your shell from there. cd'ing out of the directory erases those functions.

I've been excited about this idea for a long time now, as you can have a domain-specific language in your shell scoped to the folder you're currently in. I have made shell scripts for projects that you can either execute to perform a task, or use in dangerload to pull all the functions out of said shell script. Hit me up on Github if you/anyone feels like they'd get value out of this. I have better stuff that does this.

Answer 3

I think this is not possible to do with alias (if alias used solely).

Solutions:

• create the function inside ~/.config/fish/config.fish

    function x
      set desired_dir "/home/student/test_x" # Set your absolute path to your desired directory
      if test (pwd) = $desired_dir
        ./x.py
      else
        echo '"Alias" x :) is not allowed here! You are not in $desired_dir directory.'
      end
    end
  

  If you don't have config.fish file, create it with this code above in it.

• create the script/file with the name x under ~/bin directory with this code:

  #!/usr/bin/fish
  
  set desired_dir "/home/student/test_x" # Set your absolute path to your desired directory
  if test (pwd) = $desired_dir
    ./x.py
  else
    echo '"Alias" x :) is not allowed here! You are not in $desired_dir directory.'
  end
  

  Do not forget to make your x file executable:

  chmod u+x ~/bin/x
  

Answer 4

I Would suggest using direnv, then hook direnv into fish to set a custom variable depending on the folder.

Then, use that variable in your fish function.

direnv is an extension for your shell. It augments existing shells with a new feature that can load and unload environment variables depending on the current directory.