Align numeric values to the right (recfmt output)

Question

I'm making a Unix database in a plain text with GNU Recutils. With the following script I get a books list of a selected category:

recsel -t book -e "Category='$1'" "$RECFILE" | recfmt -f bycat.templ

The output is the following:

1: Book title
2: Book title
55: Book title
128: Book title

The file bycat.templ has the following content:

{{Id}}: {{Title}} (read: {{Read}})

It seems it's impossible to define the alignment to the right side from this file, according to the manual.

So I try to find a Unix solution, probably using printf, awk, xargs or perhaps a for bucle for every line. I don't know how to achieve this.

The desired output:

  1: Book title
  2: Book title
 55: Book title
128: Book title

Answer 1

Here you are:

File: book.awk

BEGIN {
    FS = ":"
}
{
    id = $1
    $1 = ""
    sub(/^ +/, "", $0)
    printf("%3d: %s\n", id, $0)
}

Execution:

recsel ... | recfmt ... | awk -f book.awk

Output:

  1: Book title
  2: Book title
 55: Book title
128: Book title

Answer 2

A 2-pass approach using any awk in any shell on every Unix box no matter how may digits are in the ID and no matter which characters can be present in a title (including :):

$ cat tst.awk
{
    id = title = $0
    sub(/ *:.*/,"",id)
    sub(/[^:]*: */,"",title)
}
NR==FNR {
    wid = length(id)
    maxWid = (maxWid > wid ? maxWid : wid)
    next
}
{ printf "%*s: %s\n", maxWid, id, title }

$ awk -f tst.awk file file
  1: Book title
  2: Book title
 55: Book title
128: Book title