Merge lines with the same starting field

Question

I would like to use bash tools to solve the following two related problems.

1. Suppose that I have a file with the following lines

A foo1
B bar
A foo2
A foo3 foo4
C ccc

How could I merge the lines that have the same starting field? In other words, I would like to get the following output:

A foo1 foo2 foo3 foo4
B bar
C ccc

2. After finishing the first job, there may be duplicated fields in each line. For example, foo2 may be identical to foo4. How can I remove the duplications and keep only one of them (i.e., keep only foo2)? This has to be done for each line, but we do not care about duplications across the lines.

Background: You may assume that I am compiling a dictionary. The starting field of each line is a word, and the following fields are its meanings.

Answer 1

$ awk '
    { for (i=2; i<=NF; i++) if (!seen[$1,$i]++) map[$1] = map[$1] OFS $i }
    END { for (key in map) print key map[key] }
' file
A foo1 foo2 foo3 foo4
B bar
C ccc

The above assumes you don't care about the order of the output lines.

Answer 2

cat - <<\eof > file
A foo1
B bar
A foo2
A foo3 foo2
C ccc
eof

---

awk '
{
  word = $1
  for (i=2; i<=NF; i++) {
    meaning = $i
    sep = (!(word in dict) ? "" : OFS)
    dict[word] = dict[word] \
     (!seen[meaning]++ ? sep meaning : "")
  }
}
END {
  for (word in dict)
    print word, dict[word]
}
' file

---

A foo1 foo2 foo3
B bar
C ccc