What is the un-expanded version of "$_"?

Question

In bash/zsh we use $_ representing the last argument to the previous command for later use, but this parameter contains the "expanded version" as documented. is there a thing that I can have un-expanded version of that? like in below example:

printf "%s\n" something{1..3}

I want to have access to un-expanded something{1..3} argument in the later command, not only something3.

doing this way also still adds only to very last argument not for all.

bash -c '
   printf "%s\n" "$@" && printf "%s\n" "$@"-add-something-more;
' _ something{1..3}

same in zsh, is there a way to to get that without eval trick that I don't preferer to use this way but want to show what exactly I want to have?

bash -c '
    eval printf "%s\\\n" "$@" && eval printf "%s\\\n" "$@"-add-something-more;
' _ 'something{1..3}'
something1
something2
something3
something1-add-something-more
something2-add-something-more
something3-add-something-more

Notes:

• Reading from the history is not an option as commands would executing within script and arguments would passing to the script by a user.
• I'm using command1 "$@" && command2 "$@"<question-part> syntax to execute command2 only if command1 was executed successfully.

Answer 1

To reuse a list of args more than once, that's typically what (anonymous) functions or variables are for.

In zsh:

() {cmd1 "$@" && cmd2 "$@"} something{1..3}

l=(something{1..3}); cmd1 $l && cmd2 $l

To add the same string to each argument, use the $^array syntax:

$ () {echo $@; echo $^@-more} a{1..3}
a1 a2 a3
a1-more a2-more a3-more

(the bash/ksh/zsh equivalent would be "${@/%/-more}").

To get an unexpanded version of $_, you could do something like:

TRAPDEBUG() last_cmd=($cur_cmd) cur_cmd=("${(z)ZSH_DEBUG_CMD}") 

And then:

$ echo a{1..3}; echo $last_cmd[-1]
a1 a2 a3
a{1..3}

However note that the DEBUG trap is executed before each sublist, not pipeline, let alone command. So that wouldn't work for echo a{1..3} && echo $last_cmd[-1]. You'd need:

$ eval 'echo a{1..3}' && eval 'echo $last_cmd[-1]'
a1 a2 a3
a{1..3}