Delete multiple files using rm with only one confirmation for everything (rm -i)?

Question

I have an alias rm='rm -irv' and I want to delete a bunch of files and/or directories but I only want 1 confirmation message like rm: descend into directory 'myfolder'?

I don't mind confirming for each directory but not for each file within each directory. The zsh feature for rm * or rm something/* works well but sometimes I am just deleting files rm *.txt or a single file rm document.txt but I would still like at least 1 confirmation.

This solution comes very close to what I'm looking for but does not work in every scenario. So let's say the directory "myfolder" contains 100 files then I would like something that looks like this:

~ > ls -F
myfolder/    empty.txt    file.txt    main.c

~ > rm *
zsh: sure you want to delete all 4 files in /home/user [yn]? n

~ > rm myfolder
rm: descend into directory 'myfolder'? y
removed 'file1.txt'
removed 'file2.txt'
...
removed 'file100.txt'
removed directory 'myfolder'

~ > rm main.c
rm: remove regular file 'main.c'? y
removed 'main.c'

~> rm *.txt
rm: remove all '*.txt' files? y
removed 'empty.txt'
removed 'file.txt'

Answer 1

Getting the exact prompting and output listed in your question is practically impossible (or an insane amount of work), but the following should have you covered for all practical purposes:

# Disable the default prompt that says
# 'zsh: sure you want to delete all 4 files in /home/user [yn]?'
setopt rmstarsilent

# For portability, use the `zf_rm` builtin instead of any external `rm` command.
zmodload -Fa zsh/files b:zf_rm

rm() {
  # For portability, reset all options (in this function only).
  emulate -L zsh

  # Divide the files into dirs and other files.
  # $^ treats the array as a brace expansion.
  # (N) eliminates non-existing matches.
  # (-/) matches dirs, incl. symlinks pointing to dirs.
  # (-^/) matches everything else.
  # (T) appends file type markers to the file names.
  local -a dirs=( $^@(TN-/) ) files=( $^@(TN-^/) )

  # Tell the user how many dirs and files would be deleted.
  print "Sure you want to delete these $#dirs dirs and $#files files in $PWD?"

  # List the files in columns à la `ls`, dirs first.
  print -c - $dirs $files

  # Prompt the user to confirm.
  # If `y`, delete the files.
  #   -f skips any confirmation.
  #   -r recurses into directories.
  #   -s makes sure we don't accidentally the whole thing.
  # If this succeeds, print a confirmation.
  read -q "?[yn] " &&
      zf_rm -frs - $@ && 
      print -l '' "$#dirs dirs and $#files files deleted from $PWD."
}

For more info on zf_rm, see http://zsh.sourceforge.net/Doc/Release/Zsh-Modules.html#The-zsh_002ffiles-Module

More info on glob qualifiers (TN-^/) can be found here: http://zsh.sourceforge.net/Doc/Release/Expansion.html#Glob-Qualifiers