Renaming files with non-ASCII files to append their own datetime in ASCII

Question

Multilingual environment and our file storage on linux of course allows all those international (Asian) characters in filenames. But this is causing problems syncing to other systems because the international characters all get treated by the other systems as ??? or something, and they are no longer unique filenames to those systems (culprit is MS Onedrive/Sharepoint that we're trying to sync to) -- two files in the same directory with different names (Asian characters) but having the same number of characters get treated as having identical file names, unfortunately, and we get a copy error. There seems to be no workaround except renaming files.

I want to simply append the files' own datetimes in ASCII to their filenames and this should solve it.

This command works beautifully for finding all the files that are 'problematic' for me, so to speak -- it locates all non-ASCII characters in file and folder names in /path/to/files/ and all subfolders:

find /path/to/files/ | grep -P "[\x80-\xFF]"

What I need to do with those files is append the base file name with the file's own datetime in ASCII (leaving file extension alone, as is).

Pretty much any datetime would work, either the birth, modify, change date as per stat. The information returned by these would work, for example:

stat -c '%y' filename

date -r filename

I can't figure out how to automatically append these datetimes for the files to the base filenames of the files listed by that first find command.

Answer 1

With zsh:

#! /bin/zsh -
zmodload zsh/stat
zmodload zsh/files # for its builtin mv to speed things up.
set +o multibyte -o extendedglob

# comment-out the line below once you're satisfied it does what you want.
mv() { printf 'Would rename %s to %s\n' ${(q+)2} ${(q+)3}; }

ts_format='-%FT%T.%3.%z'

# we build a $ts_pattern to be able to identify files that already have
# had a timestamp appended, by obtaining a sample timestamp for the /
# directory, and replacing all digits in it with [0-9]. That assumes you
# don't use wildcard characters nor day/month/timezone names, am/pm in your
# $ts_format.
stat -F $ts_format -A ts_sample +mtime /
ts_pattern=${ts_sample//[0-9]/[0-9]}

for file in **/(*[$'\x80'-$'\xff']*~*$~ts_pattern(.*|))(DNod); do
  stat -LF $ts_format -A ts +mtime -- $file || continue
  case $file:t in
    (?*.*) mv -- $file $file:r$ts.$file:e;; # insert ts before extension
    (*)    mv -- $file $file$ts;;
  esac
done

I hear some Microsoft OSes have issues with filenames that contain : characters so you may have to adapt the timestamp format (here in international standard format with millisecond precision 2020-08-23T08:14:38.318+0100). That's standard strftime() formatting directives, except for the %<precision>. subsecond part which is zsh-specific (there's no equivalent in strftime()).