Combining all rows in single row with coloumn seprator in unix

Question

I'm having the unix output as

ABC : 123
DEFG : 4587
MJk : 36

I want to combine all the rows in single row with same separation like

ABC DEFG MJK : 123 4587 36

I know to use awk to print output in single coloumn i.e.

awk'{print $1}' | tr '\n' ' ' 

but it is printing

ABC DEFG MJK 

not the values 123 4587 36

Answer 1

$ awk -F: '{a=a $1; b=b $2} END{print a FS b}' file
ABC DEFG MJk : 123 4587 36

We're seeing a lot of posts recently where people use tr '\n' ' ' or similar to convert newlines to something else. Except in rare situations don't do that as it converts a POSIX text file (that all POSIX text processing tools can read) into something else where YMMV. POSIX text lines end in \n and a POSIX txt file is made up of POSIX text lines. If you use tr or anything else to remove all newlines then what any subsequent POSIX text processing tool (awk, sed, etc., etc.) might do with that as input is undefined behavior.

Here's an example of some other behavior you might not expect but is actually defined by POSIX. Lets say we want to convert this multi-line string into a single space-separated line:

$ printf 'foo\nbar\n' | wc -l
       2

using tr to remove all \ns:

$ printf 'foo\nbar\n' | tr '\n' ' '
foo bar $
$ printf 'foo\nbar\n' | tr '\n' ' ' | wc -l
       0

vs a better way to do the same that outputs a POSIX text file and so gives a more intuitive result when piped to wc:

$ printf 'foo\nbar\n' | paste -sd ' ' -
foo bar
$ printf 'foo\nbar\n' | paste -sd ' ' - | wc -l
       1

Answer 2

This can be done usin the sed editor by appending the next line into tge pattern space and shuffling the fiekds around the center colon. The test command loops till the eof and inneach iteration the next line is picked.

sed -Ee '
  :a;$!N;s/(.*):(.*)\n(.*):(.*)/\1\3:\2\4/;ta
' file

The awk version is self explanatory.

awk -F ':' -v ORS='' '
{ a[NR] = $1; b[NR] = $2 }
END {
  a[NR] = a[NR] FS
  for (i=1; i<=2*NR; i++)
     print i<=NR ? a[i] : b[i-NR]
  print RS
}
' file

Result:

ABC DEFG MJK : 123 4587 36

Answer 3

It would seem that you need to buffer the entire content. You could try the following:

awk '{FNR==1{first=$1; second=$3} FNR>1{first=first " " $1; second=second " " $3} END{printf("%s : %s\n", first, second)}'

This will accumulate the contents of all "first column entries" of all lines in the variable first, and those of the "second column entries" (actually the third, because the : will form a column of its own from awks point of view) in the variable second. In the end, it prints the buffers so accumulated, with a : as separator character.

If leading/trailing whitespace is not an issue, you can shorten the code to

awk '{first=first " " $1; second=second " " $3} END{printf("%s : %s\n", first, second)}'

Answer 4

This can be done in different ways, but I leave my answer as an example without using awk.

Lets assume that your data is in file data.dat, then solution is:

echo "$(cut -d ':' -f 1 data.dat | tr '\n' ' ' | xargs) : $(cut -d ':' -f 2 data.dat | tr '\n' ' ' | xargs)"

I've got following result:

ABC DEFG MJk : 123 4587 36

Lets cut to the explanation:

• cut -d ':' -f 1 data.dat
  • cut is command to get part of line (see man cut)
  • -d ':' tells that we are using colon as delimiter
  • -f 1 tells to extract only first column (all what is left from colon in your case)
  • data.dat is simply the name of file when your original data is being stored
• tr '\n' ' ' translates changes newlines (\n) to spaces joining output strings together as one line
• xargs is here as a trick - without any args this command reprints each word trimming extra white spaces

It is almost the same with second part, except that -f 2 is used to extract string on the left of colon mark.

We are using echo command to echo results ($(...) expands command and places output of command inside brackets as a result) from two parses of file and join them with colon mark between two passes.

Answer 5

I would rather to store each column in an array and then print them in desired format

awk -F" : " '{a[NR]=$1;b[NR]=$2} END{ for(i=1;i<=NR;i++) printf "%s ",a[i]; printf ": "; for(i=1;i<=NR;i++) printf "%s ",b[i];}' file

• -F" : " separates the columns based on " : " delimiter
• {a[NR]=$1;b[NR]=$2} creates two arrays indexes = NR (number of rows) and values = value of the column in that row
• printf prints in desired order (printf will not print a newline)

Answer 6

cut and paste (and <()):

paste -s -d ' ' <(cut -d : -f 1 file) <(cut -d : -f 2 file) | paste -s -d :

Read file twice, cut to relevant fields. paste serially (twice, first separated by space, then by colon). paste -s will replace the <newline> of every line except the last line with the delimiter. If the spaces are already in the input file, change the first paste delimiter to an empty string -d ''.

Answer 7

a=`awk -F ":" '{print $1}'  filename | perl -pne "s/\n/ /g"`
b=`awk -F ":" '{print $2}'  filename | perl -pne "s/\n/ /g"`
awk -v a="$a" -v b="$b" '{print a":"b;exit}'

output

ABC  DEFG  MJk  : 123  4587  36

python

#!/usr/bin/python
k=open('o.txt','r')
a=[]
b=[]
for i in k:
    u=i.split(":")[0]
    a.append(u)
    z=i.split(":")[1]
    b.append(z.strip())
print " ".join(a) +": "+ " ".join(b)

~