awk: print last N columns but with a different field separator

Question

I have the following command with which I can change the field separator for an entire record

$ echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" | awk 'BEGIN{FS="_|-";OFS="::"} {$i=$i } 1'
DOWN::COMP::002::wget::001::6::2020::04::10::13::40::27::395533885

But i only want the last seven columns i.e 2020::04::10::13::40::27::395533885

I can try to do that with

$ echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" | awk 'BEGIN{FS="_"} {for(i=7;i<=NF;i++) printf $i"::"}'
6::2020-04-10-13::40::27::395533885::

But this will add an :: at the end which I don't want.

So how can I do this using OFS for the last N columns?

CONCLUSION FROM ANSWERS:

I was looking if there is any possible way with OFS

The solutions i saw below are not using the OFS. So its not possible using OFS

So the alternate solution is either to use sed or if inside awk which i am already aware of

So OFS is useful only when we manually do it like below

 print $1,$3,$5

Then the question is: So is there a away to generate print print $1,$3,$5.... programitcally so that OFS is automatically used.

Answer 1

In this particular case, it's probably simpler to use cut instead of awk and then sed to change the delimiter:

$ echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" | 
    cut -d_ -f6- | sed 's/_/::/g'
6::2020-04-10-13::40::27::395533885

I prefer this since getting the last N fields in awk requires a cumbersome for loop, while cut supports the N- format for "last N".

If you absolutely must use awk, you could try:

$ echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" | 
    awk -F"_" '{for(i=6;i<=NF-1;i++){printf "%s::",$i} print $NF}'
6::2020-04-10-13::40::27::395533885

Or, if you want to use - as a delimiter as well, try:

$ echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" | 
    awk -F"[-_]" '{for(i=6;i<=NF-1;i++){printf "%s::",$i} print $NF}'
6::2020::04::10::13::40::27::395533885

Answer 2

With (GNU) sed:

echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" | sed 's/_/::/6g'
DOWN_COMP_002_wget_001_6::2020-04-10-13::40::27::395533885

Please note info sed on this construct:

The 's' command can be followed by zero or more of the following FLAGS:

'g'

Apply the replacement to _all_ matches to the REGEXP, not just the first.

'NUMBER'

Only replace the NUMBERth match of the REGEXP. 

interaction in 's' command Note: the POSIX standard does not specify what should happen
when you mix the 'g' and NUMBER modifiers, and currently there is no widely agreed upon
meaning across 'sed' implementations.  For GNU 'sed', the interaction is defined to be:
ignore matches before the NUMBERth, and then match and replace all matches from the NUMBERth on.

Answer 3

I'm interpreting your question "How to do the output with OFS" as you want to perform a single print, with no arguments, and let awk insert the new field separator automatically between the fields.

To do this, you will have to rebuild $0, i.e. the current record. You can do this easily by first setting $0 to an empty string, and then assigning to the fields.

Since you empty the current record, you will have to store the data that will be put back into it in an array.

The following is an example of how this could be done:

echo 'DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885' |
awk -F '[-_]' '
        BEGIN { OFS = "::" }
        {
                nf = 0

                # save the last seven fields in "field"
                for (i = NF - 6; i <= NF; ++i)
                        field[++nf] = $i

                # clear record
                $0 = ""

                # reassign data into record
                for (i = 1; i <= nf; ++i)
                        $i = field[i]

                # output record
                print
        }'

This code outputs

2020::04::10::13::40::27::395533885

And it does this by storing the data that should be part of the output record in the array field, clearing the current record using $0 = "", and then assigning the saved data to the record before printing.

Answer 4

Use a ternary operator to select the correct delimiter:

echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" | 
    awk 'BEGIN{FS="_|-"} {for(i=6;i<=NF;i++) printf $i (i < NF ? "::" : "\n")}'

Output:

6::2020::04::10::13::40::27::395533885

Answer 5

$ echo "DOWN_COMP_002_wget_001_6_2020-04-10-13_40_27_395533885" |
    awk -v n=7 -F'[_-]' -v OFS='::' 'NF>n{sub("([^_-]*[_-]){"NF-n"}","")} {$1=$1} 1'
2020::04::10::13::40::27::395533885

Answer 6

another awk alternative:

awk -F'[_-]' -v col=7 '{ 
    while (col-->0) { printf "%s%s", $(NF-col), (col? "::" : ORS) };
}' infile

adjust col=N with "number of N last columns" you want to print.

---

Answer to the revised question to:

So is there a away to generate print print $1,$3,$5.... programitcally so that OFS is automatically used

personally and also technically there is no reason to limit yourself to using OFS, but well if you want, here is how to do it:

awk -F'[_-]' -v c=col=7 '{
    while (col-->0) { printf "%s%s", $(NF-col), (col? XXX : ORS) };
}' XXX='::' infile

but you know what is the behind OFS? replace all XXXs above with OFS; now remove XXX='::' and change XXX to just "::"; well so why stuck at using OFS then?