Displaying an indicator while zsh is looking for completions

Question

In some situations, zsh takes a long time to generate a list of completions. Maybe it needs to list some files on a remote server or maybe it needs to run a tool that has a long startup time. In these situations, after I press Tab to start completion, the screen display doesn’t change right away, and it’s not always clear whether zsh is still generating the list of completions, it has generated the list but there are no completions for the thing I’ve typed, or completion just isn’t supported in the current context.

Is there any way to display some kind of indicator while zsh builds the completion list? More generally, is there a way to have zsh run a user-defined function before it starts building the list and then have it run a different function when it’s done?

Answer 1

The entry point of completion is the function _main_complete. It calls the hook compprefuncs after setting shell options and completion-related variables and before analyzing completion display settings and performing completions. It calls the hook comppostfuncs just before returning normally, whether completions were found or not, but not before returning on a keyboard interrupt (Ctrl+C).

Each hook is an array of function names; the functions are called in order and their return status is ignored. _main_complete_ erases the array before calling the functions, so they need to re-insert themselves.

I use the zsh/terminfo module to display an indicator in the bottom right corner of the string. The completion erases this indicator, at least in the configuration that I tested.

zmodload zsh/terminfo

function set_completion_indicator {
  echoti sc # save_cursor
  echoti cup $((LINES - 1)) $((COLUMNS - $#1)) # cursor_position
  echoti setaf $2 # set_foreground (color)
  printf %s $1
  echoti sgr 0 # exit_attribute_mode
  echoti rc # restore_cursor
  #sleep 1
}

completion_indicator_text='(completing)'
completion_indicator_color=3
function display_completion_indicator {
  compprefuncs+=(display_completion_indicator)
  set_completion_indicator $completion_indicator_text $completion_indicator_color
}

function hide_completion_indicator {
  comppostfuncs+=(hide_completion_indicator)
  # The completion code erases the indicator, so there's nothing to do.
}

compprefuncs+=(display_completion_indicator)
comppostfuncs+=(hide_completion_indicator)