How to regroup string with same length using awk

Question

I have a long list of strings like this:

_ah_
_asn_
_ai_
_errr_
_an_

And I would like to transform it like to this

"_ah_ai_an_",
"_asn_",
"_errr_"

I have tried :

cat file | awk '{ print length, $0 }' | sort -n -s | cut -d" " -f2-

Which essentially sort it by length but what I am trying to do is to have those of the same length on the same line with "," As delimiters

Answer 1

$ cat tst.awk
{
    lgth = length($0)
    sub(/_$/,"",strs[lgth])
    strs[lgth] = strs[lgth] $0
}
END {
    for (lgth in strs) {
        printf "%s\"%s\"", sep, strs[lgth]
        sep = "," ORS
    }
    print ""
}

$ awk -f tst.awk file
"_ah_ai_an_",
"_asn_",
"_errr_"

Answer 2

This gives the output you want:

awk -F_ '
    {strr[length] = strr[length]"_"$2}
    length > max {max=length}
    END {
        for (i=1;i<max;i++) {if (strr[i]) print "\"" strr[i]"_\","}
        print "\"" strr[max]"_\""
    }' file

Lines with length i are appended to strr[i] with a leading _. At the end, we just loop through existing strr elements and output them with "<element>_",, except for the last element, which gets no ,.