awk print from nth column to last

Question

I want to print all columns from nth to last column of a line

Input String in file

vddp vddpi vss cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3  

Command

cat <file> | awk ' { for (i=3; i<=NF; i++)   print $i }'

Current Output

cb0
cb1
cb2
cb3
ct0
ct1
ct2
ct3

Desired Output

cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3

I am trying the awk iteration, but cannot get desired output

Answer 1

awk -v n=4 '{ for (i=n; i<=NF; i++) printf "%s%s", $i, (i<NF ? OFS : ORS)}' input

This will take n as the value of n and loop through that number through the last field NF, for each iteration it will print the current value, if that is not the last value in the line it will print OFS after it (space), if it is the last value on the line it will print ORS after it (newline).

$ echo 'vddp vddpi vss cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3' |
> awk -v n=4 '{ for (i=n; i<=NF; i++) printf "%s%s", $i, (i<NF ? OFS : ORS)}'
cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3

Answer 2

Doesn't answer your question using the awk approach requested, but I'll just point out that cut can be employed for this task.

cut -f4- -d' ' input

Answer 3

command

awk '{$1=$2=$3="";print $0}' filename| sed -r "s/^\s+//g"

command

cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3

Answer 4

If you want to preserve the spacing in between the fields that are going to be preserved, you might as well do:

<file awk '{sub(/^[[:blank:]]*([^[:blank:]]+[[:blank:]]+){3}/, ""); print}'

(though note that not all awk implementations support {3} even though it's POSIX).

That is use a regular expression that matches the first 3 fields.

Or simply use sed to do that:

<file sed 's/^[[:blank:]]*\([^[:blank:]]\{1,\}[[:blank:]]\{1,\}\)\{3\}//'

Another approach with sed is:

<file sed 's/[^[:blank:]]\{1,\}[[:blank:]]*/\
/3; s/.*\n//'

Which replaces the 3^rd field and the blanks following it with a newline and then deletes everything up to that newline.

Those assume that all the lines in the input have at least 4 fields.

On a a b c d <tab>e f <nl> input, that will give d <tab>e f <nl> output.

Answer 5

An improvement on the $1=$2=$3="" trick which works with any FS or OFS, provided that normalizing the output line to $4 OFS $5 OFS ... is acceptable:

awk 'BEGIN{p=length(OFS)*3+1} {$1=$2=$3="";print substr($0,p)}'

Assigning a value to any field (eg. $1="" or $1=$1) will cause $0 (the whole record/line) to be rebuilt (the first time it is used) by joining the $1, $2, ... fields with the OFS variable.

So $1 = $2 = $3 = "" will have the effect of setting $0 to OFS OFS OFS $4 OFS $5 ..., and the substr will get rid of leading OFSs (notice that indexes start from 1 in awk).

Answer 6

cut could get you the same result, for example

echo "one two three four" | cut -d" " -f 2-

this will give you two three four, if you were concerned about leading and trailing spaces you could squeezed the spaces with tr -s " " for example

echo "one    two  three  four   " | cut -d" " -f 2-

will give you the same result

Answer 7

with awk that supports regex in field separator, you can do:

awk -F'^[[:blank:]]*([^ \t]*[ \t]+){3}' '{ print $2 }' infile
cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3

replace number 3 in {3} with number of columns you need ignore from the beginning; and space/tab with field separator which your columns delimited with other than whitespaces; so printing $2 would be the rest of columns remaining to the end; this solution will preserve multiple whitespaces between fields if any in result.

notes: to avoid printing empty line if there was a line with equal or less than 3 fields (that indicates the # (number) of columns you need cut out) , add NF>1 to the command.

awk -F'^[[:blank:]]*([^ \t]*[ \t]+){3}' 'NF>1{ print $2 }' infile

[[:blank:]]* is used to avoid erroneous output when FS is whitespaces; if FS is something else (e.x: comma ,), then the command would be even simpler:

awk -F'^([^,]*,){3}' 'NF>1{ print $2 }' infile

Answer 8

Perl solution:

space-delimited:

perl -lane 'print "@F[3..$#F]"' file

tab-delimited:

perl -F'\t' -lane 'print join "\t", @F[3..$#F]' file

Here, the command-line flags are:
-e: tells perl interpreter to use the inline code rather than code in file.
-n: loops over the input one line at a time, assigning the input line to $_.
-l: strip the input line separator (new line in UNIX) before the code in the one-liner, and add the output line separator after the print.
-a: split each line in array @F, on whitespace by default.
-F: split on the provided pattern, rather than on whitespace.

@F[3..$#F]: fields with indexes from 3 to $#F (the last element of @F), indexes are zero-based.

Answer 9

How about

awk 'sub ("^" $1 FS $2 FS $3 FS, _)' file
cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3  

Answer 10

Tried in Python 2:

#!/usr/bin/python
k=open('filename','r')
for i in k:
    k=i.strip().split(' ')[3:]
    print " ".join(k)

output

cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3

Answer 11

print insert a newline by default. Use printf instead of print

echo "vddp vddpi vss cb0 cb1 cb2 cb3 ct0 ct1 ct2 ct3" | awk ' { for (i=4; i<=NF; i++) printf "%s " ,$i }'

For multiple lines:

cat filename.txt | awk ' { for (i=4; i<=NF; i++) 
if (i==NF) 
printf "%s\n", $i
else
printf "%s ", $i
}'

Answer 12

Retain white space after the field(s) removed:

$ sed -E 's/^[[:blank:]]*([^[:blank:]]+[[:blank:]]*){3}//' file
$ awk '{sub(/^[[:blank:]]*([^[:blank:]]+[[:blank:]]*){3}/,"")};1' file
$ grep -oP '^[[:blank:]]*([^[:blank:]]+[[:blank:]]*){3}\K.*' file

Description

There is a way to match fields with a regex: [[:blank:]]*[^[:blank:]]+.
Match an optional stream of blanks (space or tab) followed by an stream of non-blanks. If that pattern is repeated 3 times, 3 fields (with the leading white space) are matched. Then, those could be removed with any tool that is able to process regexes (with variations). Note that there may be white space before and/or after each field, that white space needs to be also matched. Matching any leading white space and the delimiting trailing white space will make the regex a bit longer: ^[[:blank:]]*([^[:blank:]]+[[:blank:]]*){n} where n is an integer that points to the last field matched.

Alternative with GNU awk:

$ awk -vrem=3 '{ 
                 n=split($0,f,FS,seps);
                 for(i=rem+1;i<=n;i++){
                                        printf("%s%s",$i,seps[i])
                                      };
                 print ""
               }
              '  file

White space collapsed

$ awk '{$1=$2=$3=""; $0=$0; $1=$1 } 1 ' file      # thanks RudiC