How to safely move and rename files based on REGEX into properly named directories

Question

In a large drive, I have multiple hundreds of files each named differently but with a few regular expressions. Each appended with random numbers and sometimes characters.

For example, there are 30 files named with a variation of the word "television", and another 50 varied from "lightbulb".

The thing is, that due to the bad coding practice I had years ago when implementing the script that generated the names, it's very inconsistent; so we might get:

• television139443.png
• elevision244904.png
• televisio097798.png
• elevisio984882.png
• _televisi90890890.png
• television-911181.png

You get the idea. That pattern applies to all the file "categories" -- "television", "lightbulb", "motorcar", etc. Luckily, there are at least 5 consistent characters in each filename which are not repeated in the other categories (a dozen cats).

What I'd like to achieve is to recursively go through the mixed folders, rename each file with the proper full title + appending creation date, and move them too their respective folder.

Sort of like:

   case : regex("levis"):
rename to Television-($creation_date).($extension)
mv to ~/Categories/Television/
break;
    case : regex("ghtbu"):
rename to Lightbulb-($creation_date).($extension)
mv to ~/Categories/Lightbulbs/
break;

Obviously this isn't proper code; it's just to illustrate the idea. I'm decently comfortable for everyday bash/zsh tasks but not fluent enough!

I would also need to gracefully handle cases where no regex is matched.

Answer 1

With zsh, you could use a different approach based on its approximate matching feature:

autoload zmv # best in ~/.zshrc
zmodload zsh/stat

dest=~/Categories
categories=(television lightbulb motorcar etc)
mkdir -p -- $dest/${(C)^categories}

zmv -n '(**/)(*[^0-9])<->(.*)' \
       '$dest/${c::=${${(CM)categories:#(#a3)$2}:-unknown}}/$c-$(
          zstat -F %FT%T%z +mtime -- $f)$3'

The ${(M)categories:#(#a3)$2} looks for $2 (the part before the number) in the categories array allowing up to three errors (different character, transposition, insertion, deletion).

Remove the -n (dry-run) if OK.

For your approach, it could be something like:

autoload zmv # best in ~/.zshrc
zmodload zsh/stat

dest=~/Categories
typeset -A categories

categories=(
  levis Television
  ghtbu Lightbulb
  otorc Motocar
)

mkdir -p -- $dest/$^categories

for k (${(k)categories}) (
  zmv -n "(**/)*$k*(.*)" '$dest/$categories[$k]/$categories[$k]-$(
          zstat -F %FT%T%z +mtime -- $f)$2'
)

Or if the common characters are always the 3^rd to 7^th:

autoload zmv # best in ~/.zshrc
zmodload zsh/stat

dest=~/Categories

categories=(Television Lightbulb Motocar)

mkdir -p -- $dest/$^categories

for c ($categories) (
  zmv -n "(**/)*$c[3,7]*(.*)" '$dest/$c/$c-$(
          zstat -F %FT%T%z +mtime -- $f)$2'
)

Answer 2

Probably not the most efficient way but I would turn the problem on it's head and match the strings within the filenames to the directories and, since the current enumeration is random, just count them in to maintain uniqueness.

homedir=~/Categories
eval homedir=$homedir

cats="Television Lightbulb Bananas Motorcar"
declare -A count

for cat in $cats; do if [ ! -d $homedir/$cat ]; then mkdir -p $homedir/$cat; fi; done

while read f; do
    r=${f##*/}
    r=${r%.*}
    r=$(grep -Po "[a-z]+" <<<$r)
    for cat in $cats; do
        if [ $(grep -i "$r" <<< $cat) ]; then
            ((count[$cat]++))
            mv "$f" $homedir/$cat/$cat-$(printf "%03g" ${count[$cat]}).${f##*.}
        fi
    done
done <<< $(find ./banana/ -type f) 

Non-matches will exit the grep loop silently and be left in place for special attention later on.

Anything else you want to include in the filename composition can go in, last modified date would be

$(stat -c %Y $f)

etc