Remove words between special chars

Question

How to remove all words between two special chars using sed? Note that the original line has to be in the result aswell.

Current code:

echo 'a "removeme" b +removeme+ c *removeme#d+removeme~ .123' | sed -r '/\W/ p; s/\W[^\W]*\W//g'

Result:

a "removeme" b +removeme+ c *removeme#d+removeme~ .123
a123

Expected result:

a "removeme" b +removeme+ c *removeme#d+removeme~ .123
a  b  c d .123

Answer 1

In your very special case, you can:

• replace all the unwanted characters by a single known character (whihc is part of that set)
• delete all the strings between two instances of that replacement character

echo 'a "removeme" b +removeme+ c *removeme#d+removeme~ .123' | sed -e '/\W/p; s/["+*#~]/#/g ; s/#[^#]\+#//g'
a "removeme" b +removeme+ c *removeme#d+removeme~ .123
a  b  c d .123

Note that since you want to keep the ., you cannot use 'non-word' class since these include the '.'. If you want to avoid giving an explicit list of characters at all costs you can:

• replace the dot by a word character that you aren't likely to encounter (thorn, slashed O, accented a/e/i/o/u, or greek/cyrillic)
• apply the expression above using [:punct:]
• reinstate the dot.

Answer 2

Change all dots to newlines, guaranteed to not be present AND ensures a non punctuation char as well. Then it's a simple matter of non greedy matching between two punctuation chars:

$  echo 'a "removeme" b +removeme+ c *removeme#d+removeme~ .123' |
   sed -e 'p
     y/./\n/
     s/[[:punct:]][^[:punct:]]*[[:punct:]]//g
     y/\n/./
   '

a "removeme" b +removeme+ c *removeme#d+removeme~ .123
a  b  c d .123

Note: this is all within Posix sed.

Answer 3

Perl is skillful at handling such cases. We use negative lookahead to create a category of punctuation chars excluding the dot :

echo '......' |
perl -lpe '
 print;
 $p = qr/(?!\.)[[:punct:]]/;
 s/$p.*?$p//g;
'