Using awk to find matches and extract characters from BEFORE each match - help!

Question

I have a problem similar to Print text before and after match, from a specific beginning and to an ending string but with a twist.

My file is a large CSV which was manually constructed. It contains the string "WAP" many times. My job is to detect all instances of the string WAP and print the character that comes two characters before each match, so long as that character is a number.

I've never needed to do string searching like this, so any guidance you can offer will be majorly helpful to my task. Thanks all.

~ daniel ~

Sample from spreadsheet: ,x,x,x,x,x,xx,Yes,"1 WAP, other stuff, other stuff",no,x

Intended output from that line: 1

this was how far I got because i've never had to use awk before:

awk '/WAP/{print}' ~/spreadsheets/waps.csv

which seems to want to print each matching line. What I think I need to do is to keep a loop running that accumulates characters up until the WAP is matched, then grabs the character two earlier. But last time I did that was in university in 1999.

Answer 1

Here is a sample awk script.

 awk '/..WAP../{print substr($0, index($0,"WAP") - 2, 7);}' input.csv

sample input:

junk
line 1 12WAP34 678
another line  abWAPcdefg
WAP123
junk WAP

output:

12WAP34
abWAPcd

explanation:

/..WAP../{                          # for line containt WAP with 2 chars wrap
    wapPosition = index($0,"WAP") - 2;  # find the position of WAP - 2 chars
    output = substr($0, wapPosition, 7);# output is 7 chars length from wapPostion
    print output;                   # print output
}

Answer 2

With GNU Awk, you could use a capture group in the match function and access its content via the optional array parameter:

$ echo ',x,x,x,x,x,xx,Yes,"1 WAP, other stuff, other stuff",no,x' | 
    awk 'match($0,/([0-9]).WAP/,a) {print a[1]}'
1

More portably, you could use a match + substr as

awk 'match($0,/[0-9].WAP/) {print substr($0,RSTART,1)}'

Answer 3

Assuming WAP can only occur once per line I think this is probably what you really want. Given this input file:

$ cat file
,x,x,x,x,x,xx,Yes,7,WAP,no,x
,x,x,x,x,x,xx,Yes,3 WAP,no,x
,x,x,x,x,x,xx,Yes,"1 WAP",no,x

With GNU awk:

$ awk 'match($0,/([0-9])[^,]WAP/,a){print a[1]}' file
3
1

With any awk:

$ awk 'match($0,/[0-9][^,]WAP/){print substr($0,RSTART,1)}' file
3
1