Find lines between two patterns and append lines with pattern

Question

We have the following file where a bunch of records (million records) of interest are between the start and end of patterns. The start pattern always start with an A and the end pattern always starts with a Z.

Apattern1   somethinghere    #start of pattern always starts with A
Line-of-data-here-aaa
Line-of-data-here-xxxxx
Zpattern1  #end of pattern always starts with Z
ApatternX   somethinghere    #Repeat: start of pattern always starts with A
Line-of-data-here-bbbb
Line-of-data-here-yyyy
Line-of-data-here-nnnnn
ZpatternX

We Want to transform the data by appending the start pattern (entire line) to the lines within the pattern. We want to remove the end pattern. We want to use sed and/or awk to append the lines that start the pattern (starts with A) to the lines within the pattern (starts with L) and get rid of the end of the pattern (always starts with Z)So the data file would look like this:

Apattern1   somethinghere  Line-of-data-here-aaa
Apattern1   somethinghere   Line-of-data-here-xxxxx
ApatternX   somethinghere   Line-of-data-here-bbbb
ApatternX   somethinghere  Line-of-data-here-yyyy
ApatternX   somethinghere  Line-of-data-here-nnnnn

Answer 1

As I understand your question you are asking for this:

sed -E '/^A/h;/^[AZ]/d;G;s/(.*)\n(.*)/\2 \1/' yourfile

So lines starting with A are copied to the hold space (/^A/h), then lines starting with either A or Z are deleted as we don't want to print them (/^[AZ]/d). For all other lines the hold space with the A line gets appended (G), both parts get exchanged separated by a whitespace instead of a newline (s/(.*)\n(.*)/\2 \1/)

(A little easier with an sed expansion I did for myself: \h in the replacement gets expanded to the contents of the hold buffer:

sed -E '/^A/h;/^[AZ]/d;G;s/^/\h /' yourfile

If I meet more questions like this, I'll do a merge request for it.)

Answer 2

sed -e '
   /^A/,/^Z/!d
   //{h;d;}
   G;s/\(.*\)\n\(.*\)/\2\t\1/
' yourfile

---

Results:

Apattern1   somethinghere       Line-of-data-here-aaa
Apattern1   somethinghere       Line-of-data-here-xxxxx
ApatternX   somethinghere       Line-of-data-here-bbbb
ApatternX   somethinghere       Line-of-data-here-yyyy
ApatternX   somethinghere       Line-of-data-here-nnnnn

---

Explanation

• Select the right range by rejecting the incorrect range: '/^A/,/^Z/!d'
• Store the range boundaries in te hold space.
• Range internals, append hold into current line and flip + change \n to tab.