Sed and Regular Expressions

Question

I've got a problem with some regular expression in sed.

I want to change a line in my file, so I did it like that:

sed -i '3s/.*/my new text in file/' file.txt.

This extension is looking for 3rd line in a file and change it.

This solution isn't good but I don't know how to build a good regular extension. Let's say that I am looking for the word 'Host' in some file. How to build a good regular extension?

I have tried the following:

sed -e '<\H...s>\ /my new text in file/' file.txt'.

What am I doing wrong?

Answer 1

Although almost no-one seems to use it, sed provides a c (change) command for whole-line replacement:

c\ 
text

    Delete the lines matching the address or address-range, and 
    output the lines of text which follow this command.

So for example you could use

sed '/\bHost\b/c\                      
my new text
' file

to change lines containing whole-word Host to my new text. The \b sequence represents a word boundary so it will exclude partial matches like Hostname - in GNU sed, you can use \< and \> instead i.e. \<Host\> and you can also put the new text on a single line:

sed '/\<Host\>/cmy new text' hostfile

which seems to be what you were aiming for in your expression - you just missed the actual c command and got the word boundary specifiers backwards i.e. <\. . .>\ in place of \<. . .\>

Answer 2

$ sed 's/^.*[[:<:]]Host[[:>:]].*$/replacement text/' file.txt

The above will replace every line in the file file.txt that contains the word Host with the string replacement text. The result will be given on standard output.

The [[:<:]] is a zero-length pattern that matches at the beginning of a word. Similarly, [[:>:]] will match at the end of a word. This means that the above substitution will not replace a line with the word Hostname or xHost on it (unless the word Host appears elsewhere on the line).