SED challenge,aggregating String containing braces

Question

I've been trying to use sed for aggregating a specific string pattern within a text for hours, but can't find the solution. I hope you guys know how to do it!?

• The text subject to my Goal consists of string characters only (No invisible \t present).

• I want to find string parts which contain (TAB), but at least two next to each other and maximum 8 adjacent to each other and replace them by a single (TAB) entry.

• The search shall be performed within a Shell file, containing a bash script

Example:

#!/bin/bash

text="Column One(TAB)(TAB)(TAB)Column Two(TAB)(TAB)Column three(TAB)Column4"

modText=`echo $text | sed 's/([(]\{1\}TAB[)]\{1\})\{2,8\}/(TAB)/g'`

• I have tried several Versions of the sed-command, the one above is just one of them. My original idea was modText=`echo $text | sed 's/\(TAB\)\{1\})\{2,8\}/(TAB)/g'`

Would be really great if you could help me out. Got the Feeling that the solution is not so far away but just don't have any more ideas and my research didn't do it :-S

---

Text Example

"Column One(TAB)(TAB)(TAB)Column Two(TAB)(TAB)Column three(TAB)Column4"

My search criteria would be matched by the first two (TAB) Groups, occurring between "Column One" and "Column three".

The result shall look like this:

"Column One(TAB)Column Two(TAB)Column three(TAB)Column4"

Answer 1

I'm not sure I understand how the "maximum 8" clause is supposed to apply, but the naive approach would be something like this:

sed 's/\((TAB)\)\{2,8\}/(TAB)/g'

Answer 2

If you mean that the replacement should not be done if there are more than 8 adjacent (TAB)s, you could do:

sed '
   s/_/_u/g; # escape _
   s/|/_p/g; # escape |
   s/(TAB)/|/g; # use a single character in place of (TAB)
   s/.*/<&>/; # add leading and trailing non-| character
   s/\([^|]\)|\{2,8\}\([^|]\)/\1|\2/; # replace up to 8 | provided
                                      # they are not preceded nor followed
                                      # by |
   s/.\(.*\)./\1/; # undo wrapping
   s/|/(TAB)/g;    # undo replacement
   s/_p/|/g;s/_u/_/g; # undo escaping'

If your sed (like ssed) supports perl-like regexps, you can use look-around operators:

ssed -R 's/(?<!\(TAB\))(\(TAB\)){2,8}(?!\(TAB\))/(TAB)/g'

Or use perl directly:

perl -lpe 's/(?<!\(TAB\))(\(TAB\)){2,8}(?!\(TAB\))/(TAB)/g'

AT&T (ast-open) sed, with the -A/-X option supports a kind of extended regular expressions they call augmented that have a negation operator (x!) and conjunction operator (x&y). There, (.{5}&(\(TAB\))!) matches a sequence of 5 characters that is not (TAB). So with that sed, you can do something like:

sed -A '
  :1
    s/(^.{0,4}|.{5}&(\(TAB\))!)(\(TAB\)){2,8}(.{0,4}$|.{5}&(\(TAB\))!)/\1(TAB)\4/
  t1'