5

How can I use awk to replace the parentheses in these 2 scenarios?

  1. Change empty parens to the word "None"

    192.168.0.24,Up,()

  2. Remove parens to only host.domain.com is left

    192.168.0.25,Up,(host.domain.com)

  • Please accept an answer if it helped resolve your question. If you have open issues, do leave a comment so that we can update the answer. – jaypal singh Jan 6 '12 at 8:25
2

With sed:

echo -e "192.168.0.25,Up,()\n1.2.3.4,Up,(host.domain.com)" | 
    sed 's/()/None/g;s/[()]//g'
192.168.0.25,Up,None
1.2.3.4,Up,host.domain.com

Here is an awk-program:

BEGIN {FS=","}
$3 ~ /\(\)/   { printf ($1","$2",None\n"); next }
$3 ~ /\(.+\)/ { 
                  gsub ("\\(", "")
                  gsub ("\\)", "")
              }
              { printf ($0"\n") }

call it with

echo -e "1.8.0.5,Up,()\n1.2.3.4,Up,(host.d.com)" | awk -f ip.awk 

for example.

  • 2
    Or add a #!/usr/bin/akw -f shebang, make it executable and call it as echo -e "...." | ip.awk – enzotib Jan 4 '12 at 7:20
2

This should work -

awk -F"," -v OFS="," '
$NF=="()" {print $1,$2,"NONE";next}
{gsub(/\(|\)/,"",$NF);print}' INPUT_FILE

Explanation:

  1. We set the Field Separator to , and Output Field Separator to ,. Setting OFS gives us the liberty to avoid printing your desired field separators explicitly.

  2. We check for a pattern $NF=="()" (where $NF is the last field), if it is true we print out the first and the second field and print NONE as the last field. Since your sample data only had three fields this approach should be ok. However, if you have more than 5 fields then using a simple for loop would be ideal. Just make sure the for loop works like i=1;i<NF;i++ this way you can manually put the final field. We also use next keyword to move to the next line since we don't want the second action to run on the first line.

  3. The second action statement is true for all the lines that don't match the first. Here we are using a global substitution built-in function which substitutes the brackets to nothing.

Test:

[jaypal:~/Temp] cat file
192.168.0.24,Up,()
192.168.0.25,Up,(host.domain.com)
192.168.0.24,Up,()
192.168.0.24,Up,()
192.168.0.25,Up,(host.domain.com)
192.168.0.25,Up,(host.domain.com)

[jaypal:~/Temp] awk -F"," -v OFS="," '
$NF=="()" {print $1,$2,"NONE";next}
{gsub(/\(|\)/,"",$NF);print}' file
192.168.0.24,Up,NONE
192.168.0.25,Up,host.domain.com
192.168.0.24,Up,NONE
192.168.0.24,Up,NONE
192.168.0.25,Up,host.domain.com
192.168.0.25,Up,host.domain.com
  • kamaal hain yaar Jaypal :-) – Nikhil Mulley Jan 4 '12 at 19:29

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.