Append based on line count in awk after pattern match

Question

How can I append lines after a pattern match in awk based on how many lines they are after the pattern match.

What I have looks like this:

Stuff
PATTERN
a b c
a b c
a b c
ENDOFSECTION
Morestuff

I would like to add various things to the of end of the lines shown as "a b c" (without knowing what a b c are specifically i.e., they are arbitrary).

Desired output:

Stuff
PATTERN
a b c   k
a b c   k
a b c   t
ENDOFSECTION
Morestuff

I think this will require some sort of loop that counts lines after the pattern is recognised. My issue is I don't know how to link the counting of lines to variable after a pattern search.

My very rough idea so far (which doesn't work):

awk '/PATTERN/ {
i=1
Do
{print $0, "   k"
i++
} while (i<=2)
}

Answer 1

awk '
  BEGIN {split("ABCDEFGH", new, "")}
  /ENDOFSECTION/ {addcol=0}
  addcol {$(++NF) = new[++i]}
  /PATTERN/ {addcol=1; i=0}
  {print}
' file

Stuff
PATTERN
a b c A
a b c B
a b c C
ENDOFSECTION
Morestuff

The BEGIN block is an example of how to create an array of new stuff to add.

Then, the awk program acts like a state machine, setting/unsetting a flag when certain patterns are seen.

Answer 2

Based on what's been clarified thus far...

awk '
    BEGIN { a="ktp" }
    /ENDOFSECTION/ { f=0 }
    f { $0=$0 "   " substr(a,++c,1) }
    /PATTERN/ { f=1 }
    { print }
'

Answer 3

awk '
/PATTERN/,/ENDOFSECTION/{
    if(/PATTERN/){
        i=0
        print
        next
    }
    if(!/ENDOFSECTION/){
        ++i
        if(i<3)
            $(NF+1)="\tk"
        else
            $(NF+1)="\tt"
    }
}
1'