Extract file name from path in awk program

Question

I have an awk script and I have passed a CSV file to it.

awk -f script.awk /home/abc/imp/asgd.csv

What am I doing is to get FILENAME within script.awk. FILENAME gives me the whole path. As I am in awk I cannot use basename FILENAME.

print FILENAME;
/home/abc/imp/asgd.csv

I have tried with this within script.awk

echo $FILENAME | awk -F"/" '{print $NF}'

but I cannot execute this within script.awk. How can I get asgd.csv within an awk program?

Answer 1

Several options:

awk '
  function basename(file) {
    sub(".*/", "", file)
    return file
  }
  {print FILENAME, basename(FILENAME)}' /path/to/file

Or:

awk '
  function basename(file, a, n) {
    n = split(file, a, "/")
    return a[n]
  }
  {print FILENAME, basename(FILENAME)}' /path/to/file

Note that those implementations of basename should work for the common cases, but not in corner cases like basename /path/to/x/// where they return the empty string instead of x or / where they return the empty string instead of /, though for regular files, that should not happen.

The first one will not work properly if the file paths (up to the last /) contain sequences of bytes that don't form valid characters in the current locale (typically this kind of thing happens in UTF-8 locales with filenames encoded in some 8 bit single byte character set). You can work around that by fixing the locale to C where every sequence of byte form valid characters.

Answer 2

Try this awk one-liner,

$ awk 'END{ var=FILENAME; split (var,a,/\//); print a[5]}' /home/abc/imp/asgd.csv
asgd.csv

Answer 3

On the systems where basename command is available, one could use awk's system() function or expression | getline var structure to call external basename command. This can help accounting for corner cases mentioned in Stephane's answer.

$ awk '{cmd=sprintf("basename %s",FILENAME);cmd | getline out; print FILENAME,out; exit}' /etc///passwd
/etc///passwd passwd

Answer 4

Use Awk's Split Function

One way to do this is to use the split function. For example:

awk '{idx = split(FILENAME, parts, "/"); print parts[idx]; nextfile}' /path/to/file

This even works on multiple files. For example:

$ awk '{idx = split(FILENAME, parts, "/"); print parts[idx]; nextfile}' \
      /etc/passwd /etc/group
passwd
group

Answer 5

Use gensub function

If you want to use it directly and only once, you can rely on gensub:

awk -F= '$1=="User" {print gensub(/.*\//, "","g",FILENAME), $2;}' /opt/ops/resources/Int_Layer_Config.sh
Int_Layer_Config.sh svcOpsInt02

• second argument is "replace by nothing"
• third argument is for repeating the pattern. it could be 1 instead since .* is greedy, but "g" is a best practice on more restrictive patterns.

And you can still assign it if you prefer, readibility in mind:

awk -F= '$1=="User" {fname=gensub(/.*\//, "","g",FILENAME); print fname, $2;}' /opt/ops/resources/Int_Layer_Config.sh
Int_Layer_Config.sh svcOpsInt02

Below a more complex usage when the filename has a meaning in the data you process. I want the first part of the name, before _

awk -F= '$1=="User" {envname=gensub(/_.*$/,"","g",gensub(/.*\//, "","g",FILENAME)); print envname, $2;}' /opt/ops/resources/*_Layer_Config.sh
Int svcOpsInt02
Dev svcDev1
Qal svcDev3

NB: The same code works inside an awk script.

Answer 6

the best way to export it from input CSV or directly from input file path you can reverse it , then get 1 column and then again reverse it.

function getFileFromPath() {
    FileName=$1
    cat $FileName | while read Filename
    do
        echo $Filename| rev | awk -v FS='/' '{print $1}' | rev 
    done
}

or simply

echo $FileNamePath| rev | awk -v FS='/' '{print $1}' | rev