Find the maximum length of characters in a field

Question

Can you tell me how to find the maximum length of characters in a given field?

For instance, with this input file:

s.no,name
1,ATM
35,money
63,back

The maximum length in field 1 is 2. So, I want the output to be:

s.no,name
01,ATM
35,money
63,back

Here, we just add the zeros before number if it is <2. Please help me.

Answer 1

First you need to find the maximum length. Comma is your field separator, and you need to ignore the first line:

len=$(awk -F, 'BEGIN{mn=0;} NR>1{n=length($1);mn=mn>n?mn:n;}END{print mn}' test.txt)

Now we use printf to expand the first field:

awk -F, 'NR==1{print $0};NR>1{ printf("%0'"$len"'d,",$1); for(i=2;i<=NF;i++)print($i); }' < test.txt

Note the single quotes end before "$len" to insert the field length and then they continue.

EDIT (thanks @dave_thompson_085 for a more elegant solution):

len=$(awk -F, 'BEGIN{mn=0} NR>1{n=length($1);mn=mn>n?mn:n;}END{print mn}' test.txt)
awk -F, -vOFS=, -vmn=$len 'NR>1{ $1=sprintf("%0*d",mn,$1)} 1' test.txt

where the last 1 means true and empty action means {print}.

Answer 2

If you just want to add a 0 if the first column is a single character, this will do:

sed -e 's/^.,/0&/' input.txt

In lines where the second character is a comma, it prepends a 0.

If the maximum length of your first column becomes 3 instead of 2, then you can do like this:

sed -e 's/^.,/00&/' -e 's/^..,/0&/' input.txt

Or, if you want to make this all dynamic, and pad as many zeros as necessary depending on the longest value in the first column, you could use this awk:

awk -F, 'NR == 1; NR > 1 { data[NR] = $0; w1[NR] = length($1); if (length($1) > max) max = length($1) } END { for (i=2; i<= NR; ++i) { w = max - w1[i]; if (w > 0) printf "%0*d", w, 0; print data[i] } }' input.txt

The same thing but expanded to multiple lines for readability, with comments:

awk -F, '
NR == 1  # the first line is the header, just print it as it is
NR > 1 {
    data[NR] = $0        # save the line
    w1[NR] = length($1)  # save the width of 1st field
    if (length($1) > max) max = length($1)  # update max length
}
END {  # pass 2: now that we know max length, print the lines
    for (i = 2; i <= NR; ++i) {
        w = max - w1[i]  # calculate the zeros we need to prepend
        if (w > 0) printf "%0*d", w, 0  # print w zeros, if necessary
        print data[i]    # print the saved line
    }
}' input.txt

Answer 3

awk '{if (length ($2)>max) max=length($2)} END {print max}' filename

The above command displays length of longest name column (i.e, $2=2nd column)