Prevent terminal from displaying previously executed command

Question

I have a script that allows me to log random thoughts while working on a project. In the terminal I would add a new log entry by running

$ @ "some random thought"

where @ is just an alias for my script.

Say my terminal is in this state:

$ ls /var/tmp
somefile.ext
another-file.l
$ _

After running my script, it would look like this:

$ ls /var/tmp
somefile.ext
another-file.l
$ @ "some random thought"
$ _

Now, I do not want that line ($ @ "some random thought") to stay on the screen after I enter it. I just want the script to run and leave no trace on the screen (some things are personal and some people might see my terminal). I also do not want to clear the entire screen.

Do you think this is possible? I am using Iterm2 if this helps.

NB: I know how to handle history so that it doesn't record my log entries. I just want to leave no trace on the screen.

Answer 1

Instead of having a command to enter your thought, you could define a widget for that. In zsh:

thought() { 
  print -r -- $BUFFER >> ~/.thoughts
  # or: your-script $BUFFER
  BUFFER=
  zle -M 'thought recorded'
}
zle -N thought
bindkey '^T' thought

Then press Ctrl-T to add the content of the buffer to your ~/.thoughts file and clear it afterwards (BUFFER=). Then, you don't have to worry about quoting.

Another approach could be to use interactive comments:

setopt interactive_comments
alias '@=:;#'
preexec() {
  [[ $1 = @* ]] && {
    print -r -- ${1#* } >> ~/.thoughts
    # or: your-script ${1#* }
    echoti cuu1
  }
}

Again, no problem with quoting, but that only works for single line thoughts. (the echoti cuu1 takes care of clearing that line by moving the cursor up).

Answer 2

Warning, this is a horrible, horrible hack (but then, the entire request is a bit of a hack). :)

Here's something that'll work on most terminals, including the braindead MS-DOS ‘ANSI.SYS’ emulator. Won't work on dumb terminals, of course (but nothing will):

tput sc
echo "This will be hidden."
sleep 5
tput rc; tput cuu 1; tput ed

Obviously, this is an example. Get rid of the echo and sleep and replace it with your command. Here's how it works:

• tput sc saves the current co-ordinates of the cursor on-screen,
• tput rc moves the cursor back to the stored co-ordinates. Now, the screen may have scrolled, so the sensitive stuff will be on the line above the saved one. So,
• tput cuu 1 moves the cursor one row up. (if you feel especially paranoid, feel free to increase the number.
• Finally, tput ed clears to the end of the screen (i.e. clears from the cursor to the end of line, then from the cursor to the bottom of the screen).

This will fail comically if the screen scrolls by a lot because sc doesn't know about scrolling, just screen co-ordinates.

tput is terminal-agnostic, so it'll work as long as your particular terminal is listed in the terminfo database and the TERM variable is correctly set.

Answer 3

You could try overwriting the previous line, which has already been answered;

How to change the contents of a line on the terminal as opposed to writing a new one?

For example (modified from original answer):

prompt% echo -n "Old line"; echo "\033[1A\033[1A" "new line"

Will display only:

prompt% new line

As the output. Adding more \033[1A sequences removes more lines.

Caveat: This doesn't work on all terminals.

Answer 4

Well, if it's just some random thought rather than actual command, then you can do so by adding space before the thought. It will exclude this command from getting into history

satish@Satish:/tmp $ echo "I'm in history"
I'm in history
satish@Satish:/tmp $  echo "I'm not"
I'm not
satish@Satish:/tmp $ history | tail -n 3
 1887  sudo su -
 1888  echo "I'm in history"
 1889  history | tail -n 3
satish@Satish:/tmp $