Sed: within the same line, stop repeating pattern replacement once a certain string is reached

Question

I can't find the answer to this anywhere. It sounds simple but I'm starting to think maybe it's not.

I want sed to remove all the CATs before the STOP in this string:

two CAT two four CAT CAT seven one STOP four CAT two CAT three

So the output I'm hoping for will be:

two two four seven one STOP four CAT CAT two CAT three

There could be any number of CATs anywhere in the string. The stop marker can be anywhere too, but just one of them, and always spelled STOP.

(Edit: as pointed out below my question is ambiguous - must CAT have adjacent spaces or can any chars border it? Maybe only non-alphanumeric chars are ok? Presenting my actual use case was intense (a big bash function) so I simplified, too much. Readers please bear in mind that solutions below may make different assumptions about adjacency. Thanks)

Answer 1

You could replace one at a time in a loop, until there are no more CATs before the STOP:

$ echo 'two CAT two four CAT CAT seven one STOP four CAT two CAT three' |
    sed -e :a -e '/CAT.*STOP/s/CAT //;ta'
two two four seven one STOP four CAT two CAT three

Answer 2

With any awk:

awk '{while($0~/CAT .*STOP/)sub(/CAT /,"")}1' file

$ echo 'two CAT two four CAT CAT seven one STOP four CAT two CAT three' |
  awk '{while($0~/CAT .*STOP/)sub(/CAT /,"")}1'
two two four seven one STOP four CAT two CAT three

Answer 3

With perl

perl -pe 's/CAT (?=.*STOP)//g'

this will replace CAT only if there is STOP is present later in the line

Answer 4

A gawk solution using STOP as a field separator and gsub out the CATs

echo 'two CAT two four CAT CAT seven one STOP four CAT two CAT three' |
  awk -F"STOP" 'BEGIN{OFS="STOP"}{gsub("CAT ","",$1)}1'

or

  awk -F"STOP" '{gsub("CAT ","",$1); print $1 FS $2}'

Answer 5

(If this is more important that just a sed puzzle, I highly recommend not doing it with sed at all. You can write this easily in python and very clearly, unlike the obscure answer here.)

You can use a loop in sed as shown below. Explanations and caveats below the code.

s/STOP/@/
: loop
s/^\([^@]*\)CAT\(.*\)$/\1\2/
t loop
s/@/STOP/
p

Run this as

$ sed -n -f t.sed

and it will fix each line as you described. Note that if no STOP is present, the code as written will remove all occurrences of CAT from the input line. Also, this code assumes that @ cannot occur in your input lines. If it does, you'll need to find another marker character.

---

So, what's going on here? Let's walk through the code:

s/STOP/@/

It is difficult in sed to write a regexp that matches the absence of something, except for the case of a single character, eg x, in which case [^x]* does the job. So, replace our sentinel STOP with a single character that we know to be unused in the rest of the line. If there is no such character, life gets a lot harder, and then we remember that sed is really not the right tool for this job.

: loop
s/^\([^@]*\)CAT\(.*\)$/\1\2/
t loop

This is the key part. : loop declares a label in your sed script that you can branch back to later. Next, in the s/// line, try to find a CAT not preceded an @ marker and replace it, preserving the text before and after. If the substitution happened, t loop will branch back to loop to try again. If the substitution failed, ie, if no such CAT is found, the branch back to loop is not taken.

s/@/STOP/
p

Restore the actual STOP text and print out the final line.