How to display the permissions of a new file in the status line of the Vim editor?

Question

With the following piece of code I get the permissions for an existing file:

augroup Get_file_perm
  autocmd!
  autocmd BufWinEnter,FileChangedShell * let w:file_perm=getfperm(expand('%:p'))
augroup END
" Output, e.g.: rw-rw-r--
set statusline=%{w:file_perm}

Unfortunately the getfperm function returns the empty string ("") for the current file path ('%:p') if it doesn't exist. I had expected the file permissions calculated from the umask.

Answer 1

To my knowledge there doesn't exist a Vim function that accomplishes what you're asking for. But I came up with my s:Get_file_perm function whose result I assign to the w:file_perm variable:

" ...
let w:file_perm=<sid>Get_file_perm()
" ...
function! s:Get_file_perm()
  let a=getfperm(expand('%:p'))
  if strlen(a)
    return a
  else
     let b=printf("%o", xor(0777,system("umask")))
     let c=""
     for d in [0, 1, 2]
       let c.=and(b[d], 4) ? "r" : "-"
       let c.=and(b[d], 2) ? "w" : "-"
       let c.=and(b[d], 1) ? "x" : "-"
     endfor
     return c
   endif
 endfunction

The function checks (if) to see if the permissions (getfperm) for the current file path ('%:p') exist (strlen). In the case of a new file ("") the else-block bitwise subtracts (xor) the octal umask from the octal literal 0777 (rwxrwxrwx) – all permission bits set.

For the owner- (0) , group- (1) and permissions for others (2) it iteratively (for) checks for each read- (4), write- (2) and execute (1) bit that it is set (and). If the corresponding bit is set it appends (.=) "r", "w" and "x" to the c variable, respectively. Else "-" is appended to symbolize that the respective operation is not permitted.